配信に使うツールをバッチファイルで一括起動する方法

配信では、OBS Studio の他に、コメントを読み上げるツールや、コメントを翻訳するツール、前の記事で使った Streamer.bot など、いくつものツールを一緒に使うことがよくあります。

Twitchの通知に反応してPNGTuberの表情を切り替える方法 Peraravatar+ で作った PNGTuber の表情を、Twitch のフォロー通知に合わせて指定のカスタム表情へ自動で切り替える手順をまとめました。 GyunGyun×Create (gyungyun.com)

そこで、「バッチファイル」を作っておきます。バッチファイルは、パソコンにさせたいこと（ここでは、ツールの起動）を上から順に書いておくファイルです。ダブルクリックすると、書いた順にツールが起動します。

この記事の対象

• バッチ処理が何なのか分からない人
• Windows を使っている人（Mac は .command ファイル、Linux はシェルスクリプトという別の仕組みを使います）

こういう記事を書くと「難しそうだから今のままでいいや…」と早い段階で離脱する人もいますが、諦めずにちょっとやってみてください。逃げるな🫵AI に書いてもらう場合まで飛ばしてAIに質問しながらやってもいいんですよ。

用意するもの

• 配信で使っているツール（インストール済みのもの）
• メモ帳（Windows にデフォルトで入っています）

メモ帳は、スタートメニューを開いて「メモ帳」と入力すると表示されます。

手順 1: ツールのパスを調べる

バッチファイルには、起動したいツールの「パス」を書きます。パスは、ファイルがパソコンのどこにあるかを表す住所です。例えば OBS Studio のパスは、デフォルトでは次のようになっています。

C:\Program Files\obs-studio\bin\64bit\obs64.exe

「C ドライブの Program Files フォルダ → obs-studio フォルダ → bin フォルダ → 64bit フォルダの中にある obs64.exe」という意味です。フォルダの区切りには \ を使います。

インストールした場所は人によって違うので、自分のパソコンでのパスを調べます。メモ帳を開いておいて、起動したいツールごとに次の手順をくり返します。

1. デスクトップにあるツールのアイコンを右クリックして、「プロパティ」を選びます。デスクトップにない場合は、スタートメニューでツールを右クリックして「ファイルの場所を開く」を選び、開いたフォルダにあるツールのアイコンを右クリックして「プロパティ」を選びます
2. 「ショートカット」タブの「リンク先」に書いてあるのが、ツールのパスです。全部選んでコピーします
3. メモ帳に貼り付けます

日本語の Windows では、\ が ¥ で表示されます。どちらも同じ文字なので、コピーしたものをそのまま使えます。

Streamer.bot のように、インストールせずに、フォルダのまま使うツールもあります。その場合は、フォルダを開いて、ツールの本体（種類が「アプリケーション」のファイル）を右クリックして、「パスのコピー」を選びます。Windows 10 では、Shift を押しながら右クリックすると「パスのコピー」が表示されます。

手順 2: バッチファイルを書く

メモ帳で新しいファイルを開いて、次のひな形を貼り付けます。

@echo off
start "" "1つ目のツールのパス"
start "" "2つ目のツールのパス"

1つ目のツールのパス と 2つ目のツールのパス の部分を、手順 1 で調べたパスに入れ替えます。

• パスの前後は " で囲みます。コピーしたパスが既に " で囲まれている場合は、" を足さずにそのまま貼り付けます
• ツールが3つ以上あるときは、start "" "パス" の行を増やします
• 1行目の @echo off は、そのまま残します

OBS Studio だけは、書き方が少し違います。パスの前に、/D と、OBS Studio のフォルダ（パスから最後の \obs64.exe を除いた部分）を書きます。これがないと、OBS Studio が起動したときにエラーになります。OBS Studio のフォルダは、手順 1 のプロパティの「作業フォルダー」に書いてあります。

start "" /D "C:\Program Files\obs-studio\bin\64bit" "C:\Program Files\obs-studio\bin\64bit\obs64.exe"

start "" /D "C:\Program Files\obs-studio\bin\64bit" "C:\Program Files\obs-studio\bin\64bit\obs64.exe" --use-fake-ui-for-media-stream --autoplay-policy=no-user-gesture-required

OBS Studio と CastCraft と Streamer.bot を起動する場合は、次のようになります。Streamer.bot のパスは、フォルダを置いた場所によって変わります。

@echo off
start "" /D "C:\Program Files\obs-studio\bin\64bit" "C:\Program Files\obs-studio\bin\64bit\obs64.exe"
start "" "C:\Users\（ユーザ名）\AppData\Local\Programs\CastCraft\CastCraft.exe"
start "" "C:\Users\（ユーザ名）\Documents\Streamer.bot-x64-1.0.7\Streamer.bot.exe"

手順 3: 保存する

1. メモ帳の「ファイル」→「名前を付けて保存」を選びます
2. 保存する場所を「デスクトップ」にします
3. 「ファイルの種類」を「すべてのファイル」にします
4. 「ファイル名」を start_streaming.bat にします
5. パスに日本語が含まれている場合は、「エンコード」を「ANSI」にします
6. 「保存」を押します

ファイル名の最後の .bat は「拡張子」といって、ファイルの種類を表します。.bat で保存すると、ダブルクリックしたときに、書いたとおりにツールを起動するファイルになります。「ファイルの種類」が「テキスト ドキュメント」のままだと、start_streaming.bat.txt のように .txt が付いて、ただのメモとして保存されます。

Windows はデフォルトで拡張子を表示しないので、start_streaming.bat.txt で保存されていても、start_streaming.bat と表示されて見分けが付きません。保存したファイルを右クリックして「プロパティ」を開き、「ファイルの種類」が「Windows バッチ ファイル (.bat)」になっていれば、正しく保存できています。

手順 4: ダブルクリックして確かめる

デスクトップに保存した start_streaming.bat をダブルクリックします。黒い画面（コマンドプロンプト）が一瞬表示されて、書いた順にツールが起動すれば完成です。次からは、配信の前にこのファイルをダブルクリックするだけで済みます。

うまくいかないときは、次のことを確かめます。

• ダブルクリックするとメモ帳が開く: .txt で保存されています。手順 3 のとおりに保存し直します
• 一部のツールだけ起動しない: そのツールのパスが合っているかを、手順 1 でもう一度確かめます
• OBS Studio がエラーになる: OBS Studio の行に /D とフォルダが書いてあるかを確かめます
• 日本語のパスのツールが起動しない: 「エンコード」を「ANSI」にして保存し直します

書いた内容を直すときは、メモ帳の「ファイル」→「開く」で start_streaming.bat を開きます。「すべてのファイル」を選ぶと、一覧に表示されます。

AI に書いてもらう場合

バッチファイルは、AI に頼んで書いてもらうこともできます。使っている AI によって、頼み方が変わります。

Codex や Claude Code など、パソコンの中を見られる AI を使っている場合

AI がパソコンの中を探してパスを調べられるので、次のように頼めば、保存まで任せられます。

配信で使っている OBS Studio と CastCraft と Streamer.bot をまとめて起動するバッチファイルを、デスクトップに start_streaming.bat という名前で作ってください。

AI がコマンドを実行する前に許可を求めてきたら、何をするのかを確かめてから許可します。ファイルの削除や設定の変更など、バッチファイルを作る以外のことをしようとしていたら、Esc で中断して問い詰めます。何をしているかよく分からない場合は「PCに詳しくない人間でも理解できるように説明してください」などの指示で説明をしてもらって、納得してから実行を許可してください。

Copilot・ChatGPT・Claude などを、ブラウザやアプリで使っている場合

AI はパソコンの中を見られないので、手順 1 で調べたパスを一緒に伝えます。Windows 11 には、Copilot がデフォルトで入っています。

配信の前に、次のツールをまとめて起動する Windows のバッチファイルを書いてください。
・OBS Studio：C:\Program Files\obs-studio\bin\64bit\obs64.exe
・CastCraft：%USERPROFILE%\AppData\Local\Programs\CastCraft\CastCraft.exe
・Streamer.bot：%USERPROFILE%\Documents\Streamer.bot-x64-1.0.7\Streamer.bot.exe

パスを伝えずに頼むと、AI はよくあるインストール先を推測して書きます。自分のパソコンのインストール先と違っていれば、そのバッチファイルではツールは起動しません。書いてもらった内容は、手順 3 と同じようにメモ帳に貼り付けて保存します。

パスの C:\Users\ の後ろには、Windows のユーザ名が入っています。ユーザ名を本名にしている場合など、AI に伝えたくないときは、C:\Users\（ユーザ名） の部分を %USERPROFILE% に書き換えて伝えます。バッチファイルの中では、%USERPROFILE% は C:\Users\（ユーザ名） と同じ場所を指します。

安全に使うために

バッチファイルは、ツールの起動だけでなく、ファイルの削除や設定の変更などの命令も実行できます。次のことに気を付けます。

• 中身を確かめてから使う: AI に書いてもらったものは、保存する前に中身を確かめます。手順 2 のひな形と同じく start の行とパスだけなら、ツールを起動するだけです。del（ファイルの削除）、rd（フォルダの削除）、reg（設定の変更）など、知らない命令が入っていたら、使う前に AI にその行が何をするのかを聞きます
• 人からもらったものは、そのまま実行しない: 人からもらったり、インターネットからダウンロードしたりしたバッチファイルは、メモ帳で開いて中身を確かめてから使います
• 「管理者として実行」しない: ツールを起動するだけなら、管理者として実行する必要はありません。普通にダブルクリックします
• ユーザ名に気を付ける: バッチファイルを人に渡したり、配信や SNS に画面を出したりするときは、パスのユーザ名が写っていないかを確かめます

おまけ: 起動後にTODOを表示する

ツールを起動しても、配信情報の更新や CastCraft への接続など、それぞれのツールでやることをうっかり忘れてしまう人もいるかと思います。せっかく一括起動できるようになったのに、結局配信中に「あ！忘れてた！」と手を止めることにならないようにTODOリストの機能も詰め込みましょう。バッチファイルの最後に、やることの一覧を表示するようにしておくと、1つずつ確かめてから配信を始められます。

手順 2 の例に、やることの一覧を追加すると、次のようになります。

@echo off
setlocal enabledelayedexpansion
start "" /D "C:\Program Files\obs-studio\bin\64bit" "C:\Program Files\obs-studio\bin\64bit\obs64.exe"
start "" "C:\Users\（ユーザ名）\AppData\Local\Programs\CastCraft\CastCraft.exe"
start "" "C:\Users\（ユーザ名）\Documents\Streamer.bot-x64-1.0.7\Streamer.bot.exe"

set "TODO1=配信情報の更新"
set "TODO2=CastCraft への接続"

set COUNT=0
for /l %%n in (1,1,99) do if defined TODO%%n set COUNT=%%n
set DONE=0

:CHECK
cls
echo Checklist
echo.
for /l %%n in (1,1,%COUNT%) do (
  if %%n leq !DONE! (echo   [OK] !TODO%%n!) else (echo   [  ] !TODO%%n!)
)
echo.
if %DONE% geq %COUNT% exit 0
set /a NEXT=DONE+1
set /p "ANSWER=Press Enter when done: !TODO%NEXT%!"
set DONE=%NEXT%
goto CHECK

ツールを起動したあと、コマンドプロンプトにやることの一覧が表示されます。一番上の項目から順に、済んだら Enter キーを押します。

Enter キーを押すと、その項目に [OK] が付いて、次の項目に進みます。最後の項目で Enter キーを押すと、コマンドプロンプトが閉じます。

やることは、set "TODO1=…" の行に書きます。

• 項目を増やすときは、set "TODO3=…" のように、番号を1つずつ増やした行を追加します
• 2行目の setlocal enabledelayedexpansion は、そのまま残します
• やることを日本語で書いたときは、手順 3 で「エンコード」を「ANSI」にして保存します

まとめ

• 配信で使うツールの起動は、バッチファイルにまとめておくと、ダブルクリック1回で済む
• ツールのパスは、アイコンのプロパティの「リンク先」か、右クリックの「パスのコピー」で調べる
• メモ帳でひな形のパスの部分を書き換えて、.bat で保存する。OBS Studio は /D とフォルダも書く
• Codex や Claude Code などパソコンの中を見られる AI なら、パスを調べるところから任せられる。ブラウザやアプリの AI には、自分で調べたパスを伝える
• AI に書いてもらったものや、人からもらったバッチファイルは、中身を確かめる